NOISSUE change uvim folder name to mnv

Signed-off-by: Mehmet Samet Duman <yongdohyun@projecttick.org>

1 files changed, 40 insertions, 0 deletions

diff --git a/mnv/runtime/ftplugin/svelte.mnv b/mnv/runtime/ftplugin/svelte.mnv
new file mode 100644
index 0000000000..9099e4bcad
--- /dev/null
+++ b/mnv/runtime/ftplugin/svelte.mnv
@@ -0,0 +1,40 @@
+" MNV filetype plugin
+" Language:	svelte
+" Maintainer:	Igor Lacerda <igorlafarsi@gmail.com>
+" Last Change:	2025 Apr 06
+
+if exists('b:did_ftplugin')
+  finish
+endif
+let b:did_ftplugin = 1
+
+let s:cpo_sav = &cpo
+set cpo&mnv
+
+setlocal matchpairs+=<:>
+setlocal commentstring=<!--\ %s\ -->
+setlocal comments=s:<!--,m:\ \ \ \ ,e:-->
+
+let b:undo_ftplugin = 'setlocal comments< commentstring< matchpairs<'
+
+if exists('&omnifunc')
+  setlocal omnifunc=htmlcomplete#CompleteTags
+  call htmlcomplete#DetectOmniFlavor()
+  let b:undo_ftplugin ..= " | setlocal omnifunc<"
+endif
+
+if exists("loaded_matchit") && !exists("b:match_words")
+  let b:match_ignorecase = 1
+  let b:match_words = '<:>,' .
+    \ '<\@<=[ou]l\>[^>]*\%(>\|$\):<\@<=li\>:<\@<=/[ou]l>,' .
+    \ '<\@<=dl\>[^>]*\%(>\|$\):<\@<=d[td]\>:<\@<=/dl>,' .
+    \ '<\@<=\([^/][^ \t>]*\)[^>]*\%(>\|$\):<\@<=/\1>,' .
+    \ '{#\(if\|each\)[^}]*}:{\:else[^}]*}:{\/\(if\|each\)},' .
+    \ '{#await[^}]*}:{\:then[^}]*}:{\:catch[^}]*}:{\/await},' .
+    \ '{#snippet[^}]*}:{\/snippet},' .
+    \ '{#key[^}]*}:{\/key}'
+  let b:html_set_match_words = 1
+  let b:undo_ftplugin ..= " | unlet! b:match_ignorecase b:match_words b:html_set_match_words"
+endif
+let &cpo = s:cpo_sav
+unlet! s:cpo_sav