NOISSUE add archived projects

Signed-off-by: Mehmet Samet Duman <yongdohyun@projecttick.org>

8 files changed, 475 insertions, 0 deletions

diff --git a/archived/ptlibzippy/contrib/puff/test/CMakeLists.txt b/archived/ptlibzippy/contrib/puff/test/CMakeLists.txt
new file mode 100644
index 0000000000..c623162ef2
--- /dev/null
+++ b/archived/ptlibzippy/contrib/puff/test/CMakeLists.txt
@@ -0,0 +1,278 @@
+# if we are built from with PTlibzippy, use this path's)
+if(DEFINED PTLIBZIPPY_BUILD_PUFF)
+    set(WORK_DIR ${PTlibzippy_BINARY_DIR})
+    set(inst_setup ptlibzippy_install)
+else(DEFINED PTLIBZIPPY_BUILD_PUFF)
+    set(WORK_DIR ${puff_BINARY_DIR})
+    set(inst_setup ptlibzippy_puff_install)
+
+    add_test(
+        NAME ptlibzippy_puff_install
+        COMMAND ${CMAKE_COMMAND} --install ${puff_BINARY_DIR} --prefix
+                ${CMAKE_CURRENT_BINARY_DIR}/test_install --config $<CONFIG>
+        WORKING_DIRECTORY ${puff_BINARY_DIR})
+
+    set_tests_properties(ptlibzippy_puff_install
+        PROPERTIES
+            FIXTURES_SETUP ptlibzippy_puff_install)
+endif(DEFINED PTLIBZIPPY_BUILD_PUFF)
+
+set(PUFF_TEST_INSTALL_DIR "${WORK_DIR}/test/test_install")
+set(PUFF_TEST_PACKAGE_DIR
+    "${PUFF_TEST_INSTALL_DIR}/${CMAKE_INSTALL_LIBDIR}/cmake/puff")
+if(DEFINED PTLIBZIPPY_BUILD_PUFF)
+    set(PTLIBZIPPY_TEST_PACKAGE_DIR
+        "${PUFF_TEST_INSTALL_DIR}/${CMAKE_INSTALL_LIBDIR}/cmake/ptlibzippy")
+else()
+    set(PTLIBZIPPY_TEST_PACKAGE_DIR "${PTlibzippy_DIR}")
+endif()
+set(PUFF_FIND_PACKAGE_ARGS
+    "-Dpuff_DIR=${PUFF_TEST_PACKAGE_DIR}"
+    "-DPTlibzippy_DIR=${PTLIBZIPPY_TEST_PACKAGE_DIR}")
+
+if(PTLIBZIPPY_PUFF_BUILD_SHARED AND NOT WIN32)
+    add_executable(ptlibzippy_puff_test
+        ${puff_SOURCE_DIR}/pufftest.c
+        ${puff_SOURCE_DIR}/puff.h)
+
+    target_link_libraries(ptlibzippy_puff_test
+        PRIVATE ptlibzippy_puff_puff)
+
+    add_test(NAME ptlibzippy_puff_test
+        COMMAND ${CMAKE_COMMAND} -P
+                ${CMAKE_CURRENT_SOURCE_DIR}/tester.cmake
+                "$<TARGET_FILE:ptlibzippy_puff_test>"
+                "${puff_SOURCE_DIR}")
+
+    if(GCOV_EXECUTABLE)
+        add_executable(ptlibzippy_puff_test-coverage
+            ${puff_SOURCE_DIR}/pufftest.c
+            ${puff_SOURCE_DIR}/puff.c
+            ${puff_SOURCE_DIR}/puff.h)
+
+        target_compile_options(ptlibzippy_puff_test-coverage PRIVATE -coverage)
+
+        target_link_options(ptlibzippy_puff_test-coverage PRIVATE -coverage)
+
+        add_test(NAME ptlibzippy_puff_test-coverage
+            COMMAND ${CMAKE_COMMAND} -P
+                    ${CMAKE_CURRENT_SOURCE_DIR}/tester-cov.cmake
+                    "$<TARGET_FILE:ptlibzippy_puff_test-coverage>"
+                    "${puff_SOURCE_DIR}"
+                    "$<TARGET_FILE:ptlibzippy_puff_bin-writer>"
+                    ${GCOV_EXECUTABLE}
+                    ${llvm_option})
+    endif(GCOV_EXECUTABLE)
+endif(PTLIBZIPPY_PUFF_BUILD_SHARED AND NOT WIN32)
+
+if(PTLIBZIPPY_PUFF_BUILD_STATIC AND NOT WIN32)
+    add_executable(ptlibzippy_puff_testStatic
+        ${puff_SOURCE_DIR}/pufftest.c
+        ${puff_SOURCE_DIR}/puff.h)
+
+    target_link_libraries(ptlibzippy_puff_testStatic
+        PRIVATE ptlibzippy_puff_puffStatic)
+    add_test(NAME ptlibzippy_puff_testStatic
+        COMMAND ${CMAKE_COMMAND} -P
+                ${CMAKE_CURRENT_SOURCE_DIR}/tester.cmake
+                "$<TARGET_FILE:ptlibzippy_puff_testStatic>"
+                "${puff_SOURCE_DIR}")
+
+    if(GCOV_EXECUTABLE)
+        add_executable(ptlibzippy_puff_testStatic-coverage
+            ${puff_SOURCE_DIR}/pufftest.c
+            ${puff_SOURCE_DIR}/puff.c
+            ${puff_SOURCE_DIR}/puff.h)
+
+        target_compile_options(ptlibzippy_puff_testStatic-coverage
+            PRIVATE -coverage)
+
+        target_link_options(ptlibzippy_puff_testStatic-coverage
+            PRIVATE -coverage)
+
+        add_test(NAME ptlibzippy_puff_testStatic-coverage
+            COMMAND ${CMAKE_COMMAND} -P
+                ${CMAKE_CURRENT_SOURCE_DIR}/tester-cov.cmake
+                "$<TARGET_FILE:ptlibzippy_puff_testStatic-coverage>"
+                "${puff_SOURCE_DIR}"
+                "$<TARGET_FILE:ptlibzippy_puff_bin-writer>"
+                ${GCOV_EXECUTABLE}
+                ${llvm_option})
+    endif(GCOV_EXECUTABLE)
+endif(PTLIBZIPPY_PUFF_BUILD_STATIC AND NOT WIN32)
+
+file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/findpackage_test)
+file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/add_subdirectory_test)
+file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/add_subdirectory_exclude_test)
+
+configure_file(
+    ${CMAKE_CURRENT_SOURCE_DIR}/find_package_test.cmake.in
+    ${CMAKE_CURRENT_BINARY_DIR}/findpackage_test/CMakeLists.txt @ONLY)
+
+configure_file(
+    ${CMAKE_CURRENT_SOURCE_DIR}/add_subdirectory_test.cmake.in
+    ${CMAKE_CURRENT_BINARY_DIR}/add_subdirectory_test/CMakeLists.txt @ONLY)
+
+configure_file(
+    ${CMAKE_CURRENT_SOURCE_DIR}/add_subdirectory_exclude_test.cmake.in
+    ${CMAKE_CURRENT_BINARY_DIR}/add_subdirectory_exclude_test/CMakeLists.txt
+    @ONLY)
+
+configure_file(
+    ${CMAKE_CURRENT_SOURCE_DIR}/find_package_no_components_test.cmake.in
+    ${CMAKE_CURRENT_BINARY_DIR}/findpackage_no_components_test/CMakeLists.txt
+    @ONLY)
+
+configure_file(
+    ${CMAKE_CURRENT_SOURCE_DIR}/find_package_wrong_components_test.cmake.in
+    ${CMAKE_CURRENT_BINARY_DIR}/findpackage_wrong_components_test/CMakeLists.txt
+    @ONLY)
+
+# CMAKE_GENERATOR_PLATFORM doesn't work in the if
+set(GENERATOR ${CMAKE_GENERATOR_PLATFORM})
+
+if(GENERATOR)
+    set(PLATFORM "-A ${GENERATOR}")
+endif(GENERATOR)
+
+#
+# findpackage_test
+#
+add_test(
+    NAME ptlibzippy_puff_find_package_configure
+    COMMAND
+        ${CMAKE_COMMAND}
+        ${PLATFORM}
+        -B${CMAKE_CURRENT_BINARY_DIR}/findpackage_test_build
+        -DCMAKE_BUILD_TYPE=$<CONFIG>
+        -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+        -DCMAKE_C_FLAGS=${CMAKE_C_FLAGS}
+        -DCMAKE_INSTALL_PREFIX=${PUFF_TEST_INSTALL_DIR}
+        ${PUFF_FIND_PACKAGE_ARGS}
+        --fresh
+        -G "${CMAKE_GENERATOR}"
+        -S${CMAKE_CURRENT_BINARY_DIR}/findpackage_test)
+
+add_test(
+    NAME ptlibzippy_puff_find_package_build
+    COMMAND ${CMAKE_COMMAND} --build . --config $<CONFIG>
+    WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/findpackage_test_build)
+
+set_tests_properties(ptlibzippy_puff_find_package_configure
+    PROPERTIES
+        FIXTURES_REQUIRED ${inst_setup}
+        FIXTURES_SETUP puff_fp_config)
+
+set_tests_properties(ptlibzippy_puff_find_package_build
+    PROPERTIES
+        FIXTURES_REQUIRED puff_fp_config)
+
+#
+# add_subdirectory_test
+#
+add_test(
+    NAME ptlibzippy_puff_add_subdirectory_configure
+    COMMAND
+        ${CMAKE_COMMAND} ${PLATFORM}
+        -B${CMAKE_CURRENT_BINARY_DIR}/add_subdirectory_test_build
+        -DCMAKE_BUILD_TYPE=$<CONFIG>
+        -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+        -DCMAKE_C_FLAGS=${CMAKE_C_FLAGS}
+        -DCMAKE_INSTALL_PREFIX=${PUFF_TEST_INSTALL_DIR}
+        ${PUFF_FIND_PACKAGE_ARGS}
+        --fresh
+        -G "${CMAKE_GENERATOR}"
+        -S${CMAKE_CURRENT_BINARY_DIR}/add_subdirectory_test)
+
+add_test(
+    NAME ptlibzippy_puff_add_subdirectory_build
+    COMMAND ${CMAKE_COMMAND} --build . --config $<CONFIG>
+    WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/add_subdirectory_test_build)
+
+set_tests_properties(ptlibzippy_puff_add_subdirectory_configure
+    PROPERTIES
+        FIXTURES_REQUIRED ${inst_setup}
+        FIXTURES_SETUP puff_as_config)
+
+set_tests_properties(ptlibzippy_puff_add_subdirectory_build
+    PROPERTIES
+        FIXTURES_REQUIRED puff_as_config)
+
+#
+# add_subdirectory_exclude_test
+#
+add_test(
+    NAME ptlibzippy_puff_add_subdirectory_exclude_configure
+    COMMAND
+        ${CMAKE_COMMAND} ${PLATFORM}
+        -B${CMAKE_CURRENT_BINARY_DIR}/add_subdirectory_exclude_test_build
+        -DCMAKE_BUILD_TYPE=$<CONFIG> -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+        -DCMAKE_C_FLAGS=${CMAKE_C_FLAGS}
+        -DCMAKE_INSTALL_PREFIX=${PUFF_TEST_INSTALL_DIR}
+        ${PUFF_FIND_PACKAGE_ARGS}
+        --fresh
+        -G "${CMAKE_GENERATOR}"
+        -S${CMAKE_CURRENT_BINARY_DIR}/add_subdirectory_exclude_test)
+
+add_test(
+    NAME ptlibzippy_puff_add_subdirectory_exclude_build
+    COMMAND ${CMAKE_COMMAND} --build . --config $<CONFIG>
+    WORKING_DIRECTORY
+        ${CMAKE_CURRENT_BINARY_DIR}/add_subdirectory_exclude_test_build)
+
+set_tests_properties(ptlibzippy_puff_add_subdirectory_exclude_configure
+    PROPERTIES
+        FIXTURES_REQUIRED ${inst_setup}
+        FIXTURES_SETUP puff_asx_config)
+
+set_tests_properties(ptlibzippy_puff_add_subdirectory_exclude_build
+    PROPERTIES
+        FIXTURES_REQUIRED puff_asx_config)
+
+#
+# findpackage_no_components_test
+#
+add_test(
+    NAME ptlibzippy_puff_find_package_no_components_configure
+    COMMAND
+        ${CMAKE_COMMAND} ${PLATFORM}
+        -B${CMAKE_CURRENT_BINARY_DIR}/findpackage_no_components_test_build
+        -DCMAKE_BUILD_TYPE=$<CONFIG> -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+        -DCMAKE_C_FLAGS=${CMAKE_C_FLAGS}
+        -DCMAKE_INSTALL_PREFIX=${PUFF_TEST_INSTALL_DIR}
+        ${PUFF_FIND_PACKAGE_ARGS}
+        --fresh
+        -G "${CMAKE_GENERATOR}"
+        -S${CMAKE_CURRENT_BINARY_DIR}/findpackage_no_components_test)
+
+set_tests_properties(
+    ptlibzippy_puff_find_package_no_components_configure
+        PROPERTIES
+            FIXTURES_REQUIRED ${inst_setup})
+
+if(NOT PTLIBZIPPY_PUFF_BUILD_SHARED OR NOT PTLIBZIPPY_PUFF_BUILD_STATIC)
+    set_tests_properties(ptlibzippy_puff_find_package_no_components_configure
+        PROPERTIES
+            WILL_FAIL TRUE)
+endif(NOT PTLIBZIPPY_PUFF_BUILD_SHARED OR NOT PTLIBZIPPY_PUFF_BUILD_STATIC)
+
+#
+# findpackage_no_components_test
+#
+add_test(
+    NAME ptlibzippy_puff_find_package_wrong_components_configure
+    COMMAND
+        ${CMAKE_COMMAND} ${PLATFORM}
+        -B${CMAKE_CURRENT_BINARY_DIR}/findpackage_wrong_components_test_build
+        -DCMAKE_BUILD_TYPE=$<CONFIG> -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+        -DCMAKE_C_FLAGS=${CMAKE_C_FLAGS}
+        -DCMAKE_INSTALL_PREFIX=${PUFF_TEST_INSTALL_DIR}
+        ${PUFF_FIND_PACKAGE_ARGS}
+        --fresh
+        -G "${CMAKE_GENERATOR}"
+        -S${CMAKE_CURRENT_BINARY_DIR}/findpackage_wrong_components_test)
+
+set_tests_properties(ptlibzippy_puff_find_package_wrong_components_configure
+    PROPERTIES
+        FIXTURES_REQUIRED ${inst_setup}
+        WILL_FAIL TRUE)
diff --git a/archived/ptlibzippy/contrib/puff/test/add_subdirectory_exclude_test.cmake.in b/archived/ptlibzippy/contrib/puff/test/add_subdirectory_exclude_test.cmake.in
new file mode 100644
index 0000000000..b01ccbd928
--- /dev/null
+++ b/archived/ptlibzippy/contrib/puff/test/add_subdirectory_exclude_test.cmake.in
@@ -0,0 +1,26 @@
+cmake_minimum_required(VERSION 3.12...3.31)
+
+project(
+    ptlibzippy_puff_add_subdirectory_exclude_from_all
+    LANGUAGES C
+    VERSION @puff_VERSION@)
+
+option(PTLIBZIPPY_PUFF_BUILD_TESTING "" OFF)
+option(PTLIBZIPPY_PUFF_BUILD_SHARED "" @PTLIBZIPPY_PUFF_BUILD_SHARED@)
+option(PTLIBZIPPY_PUFF_BUILD_STATIC "" @PTLIBZIPPY_PUFF_BUILD_STATIC@)
+
+add_subdirectory(@puff_SOURCE_DIR@ ${CMAKE_CURRENT_BINARY_DIR}/puff
+                 EXCLUDE_FROM_ALL)
+
+set(PUFF_SRCS
+    @puff_SOURCE_DIR@/pufftest.c)
+
+if(PTLIBZIPPY_PUFF_BUILD_SHARED)
+    add_executable(test_example ${PUFF_SRCS})
+    target_link_libraries(test_example PUFF::PUFF)
+endif(PTLIBZIPPY_PUFF_BUILD_SHARED)
+
+if(PTLIBZIPPY_PUFF_BUILD_STATIC)
+    add_executable(test_example_static ${PUFF_SRCS})
+    target_link_libraries(test_example_static PUFF::PUFFSTATIC)
+endif(PTLIBZIPPY_PUFF_BUILD_STATIC)
diff --git a/archived/ptlibzippy/contrib/puff/test/add_subdirectory_test.cmake.in b/archived/ptlibzippy/contrib/puff/test/add_subdirectory_test.cmake.in
new file mode 100644
index 0000000000..8a11682efd
--- /dev/null
+++ b/archived/ptlibzippy/contrib/puff/test/add_subdirectory_test.cmake.in
@@ -0,0 +1,25 @@
+cmake_minimum_required(VERSION 3.12...3.31)
+
+project(
+    ptlibzippy_puff_add_subdirectory
+    LANGUAGES C
+    VERSION @puff_VERSION@)
+
+option(PTLIBZIPPY_PUFF_BUILD_TESTING "" OFF)
+option(PTLIBZIPPY_PUFF_BUILD_SHARED "" @PTLIBZIPPY_PUFF_BUILD_SHARED@)
+option(PTLIBZIPPY_PUFF_BUILD_STATIC "" @PTLIBZIPPY_PUFF_BUILD_STATIC@)
+
+add_subdirectory(@puff_SOURCE_DIR@ ${CMAKE_CURRENT_BINARY_DIR}/puff)
+
+set(PUFF_SRCS
+    @puff_SOURCE_DIR@/pufftest.c)
+
+if(PTLIBZIPPY_PUFF_BUILD_SHARED)
+    add_executable(test_example ${PUFF_SRCS})
+    target_link_libraries(test_example PUFF::PUFF)
+endif(PTLIBZIPPY_PUFF_BUILD_SHARED)
+
+if(PTLIBZIPPY_PUFF_BUILD_STATIC)
+    add_executable(test_example_static ${PUFF_SRCS})
+    target_link_libraries(test_example_static PUFF::PUFFSTATIC)
+endif(PTLIBZIPPY_PUFF_BUILD_STATIC)
diff --git a/archived/ptlibzippy/contrib/puff/test/find_package_no_components_test.cmake.in b/archived/ptlibzippy/contrib/puff/test/find_package_no_components_test.cmake.in
new file mode 100644
index 0000000000..7e43e4d317
--- /dev/null
+++ b/archived/ptlibzippy/contrib/puff/test/find_package_no_components_test.cmake.in
@@ -0,0 +1,24 @@
+cmake_minimum_required(VERSION 3.12...3.31)
+
+project(
+    puff_find_package
+    LANGUAGES C
+    VERSION @puff_VERSION@)
+
+option(PTLIBZIPPY_PUFF_BUILD_SHARED "" @PTLIBZIPPY_PUFF_BUILD_SHARED@)
+option(PTLIBZIPPY_PUFF_BUILD_STATIC "" @PTLIBZIPPY_PUFF_BUILD_STATIC@)
+
+find_package(puff REQUIRED CONFIG)
+
+set(PUFF_SRCS
+    @puff_SOURCE_DIR@/pufftest.c)
+
+if(PTLIBZIPPY_PUFF_BUILD_SHARED)
+    add_executable(test_example ${PUFF_SRCS})
+    target_link_libraries(test_example PUFF::PUFF)
+endif(PTLIBZIPPY_PUFF_BUILD_SHARED)
+
+if(PTLIBZIPPY_PUFF_BUILD_STATIC)
+    add_executable(test_example_static ${PUFF_SRCS})
+    target_link_libraries(test_example_static PUFF::PUFFSTATIC)
+endif(PTLIBZIPPY_PUFF_BUILD_STATIC)
diff --git a/archived/ptlibzippy/contrib/puff/test/find_package_test.cmake.in b/archived/ptlibzippy/contrib/puff/test/find_package_test.cmake.in
new file mode 100644
index 0000000000..6888468a9f
--- /dev/null
+++ b/archived/ptlibzippy/contrib/puff/test/find_package_test.cmake.in
@@ -0,0 +1,24 @@
+cmake_minimum_required(VERSION 3.12...3.31)
+
+project(
+    puff_find_package
+    LANGUAGES C
+    VERSION @puff_VERSION@)
+
+option(PTLIBZIPPY_PUFF_BUILD_SHARED "" @PTLIBZIPPY_PUFF_BUILD_SHARED@)
+option(PTLIBZIPPY_PUFF_BUILD_STATIC "" @PTLIBZIPPY_PUFF_BUILD_STATIC@)
+
+set(PUFF_SRCS
+    @puff_SOURCE_DIR@/pufftest.c)
+
+if(PTLIBZIPPY_PUFF_BUILD_SHARED)
+    find_package(puff REQUIRED COMPONENTS shared CONFIG)
+    add_executable(test_example ${PUFF_SRCS})
+    target_link_libraries(test_example PUFF::PUFF)
+endif(PTLIBZIPPY_PUFF_BUILD_SHARED)
+
+if(PTLIBZIPPY_PUFF_BUILD_STATIC)
+    find_package(puff REQUIRED COMPONENTS static CONFIG)
+    add_executable(test_example_static ${PUFF_SRCS})
+    target_link_libraries(test_example_static PUFF::PUFFSTATIC)
+endif(PTLIBZIPPY_PUFF_BUILD_STATIC)
diff --git a/archived/ptlibzippy/contrib/puff/test/find_package_wrong_components_test.cmake.in b/archived/ptlibzippy/contrib/puff/test/find_package_wrong_components_test.cmake.in
new file mode 100644
index 0000000000..8b426c5178
--- /dev/null
+++ b/archived/ptlibzippy/contrib/puff/test/find_package_wrong_components_test.cmake.in
@@ -0,0 +1,24 @@
+cmake_minimum_required(VERSION 3.12...3.31)
+
+project(
+    puff_find_package
+    LANGUAGES C
+    VERSION @puff_VERSION@)
+
+option(PTLIBZIPPY_PUFF_BUILD_SHARED "" @PTLIBZIPPY_PUFF_BUILD_SHARED@)
+option(PTLIBZIPPY_PUFF_BUILD_STATIC "" @PTLIBZIPPY_PUFF_BUILD_STATIC@)
+
+find_package(puff REQUIRED COMPONENTS wrong CONFIG)
+
+set(PUFF_SRCS
+    @puff_SOURCE_DIR@/pufftest.c)
+
+if(PTLIBZIPPY_PUFF_BUILD_SHARED)
+    add_executable(test_example ${PUFF_SRCS})
+    target_link_libraries(test_example PUFF::PUFF)
+endif(PTLIBZIPPY_PUFF_BUILD_SHARED)
+
+if(PTLIBZIPPY_PUFF_BUILD_STATIC)
+    add_executable(test_example_static ${PUFF_SRCS})
+    target_link_libraries(test_example_static PUFF::PUFFSTATIC)
+endif(PTLIBZIPPY_PUFF_BUILD_STATIC)
diff --git a/archived/ptlibzippy/contrib/puff/test/tester-cov.cmake b/archived/ptlibzippy/contrib/puff/test/tester-cov.cmake
new file mode 100644
index 0000000000..a91c6fd91a
--- /dev/null
+++ b/archived/ptlibzippy/contrib/puff/test/tester-cov.cmake
@@ -0,0 +1,58 @@
+cmake_minimum_required(VERSION 3.12...3.31)
+
+#CMAKE_ARGV0 = ${CMAKE_COMMAND}
+#CMAKE_ARGV1 = -P
+#CMAKE_ARGV2 = ${CMAKE_CURRENT_SOURCE_DIR}/tester-cov.cmake
+#CMAKE_ARGV3 = "$<TARGET_FILE:puff-test-cov>"
+#CMAKE_ARGV4 = "${CMAKE_CURRENT_SOURCE_DIR}"
+#CMAKE_ARGV5 = "${CMAKE_CURRENT_BINARY_DIR}"
+#CMAKE_ARGV6 = GCOV_EXECUTABLE
+#CMAKE_ARGV7 = GCOV_EXECUTABLE
+
+function(puff_cov_test test_string expected_result)
+    execute_process(COMMAND ${CMAKE_ARGV0} -E echo_append ${test_string}
+                    COMMAND ${CMAKE_ARGV5}
+                    COMMAND ${CMAKE_ARGV3}
+                    RESULT_VARIABLE RESULT)
+
+    if(NOT RESULT EQUAL expected_result)
+        message(FATAL_ERROR "Received Exit-Code: ${RESULT}\n"
+                            "Expected Exit-Code: ${expected_result}\n"
+                            "Test-String: ${test_string}")
+    endif(NOT RESULT EQUAL expected_result)
+endfunction(puff_cov_test test_string expected_result)
+
+execute_process(COMMAND ${CMAKE_ARGV3} -w ${CMAKE_ARGV4}/zeros.raw)
+
+puff_cov_test("04" "2")
+puff_cov_test("00" "2")
+puff_cov_test("00 00 00 00 00" "254")
+puff_cov_test("00 01 00 fe ff" "2")
+
+execute_process(COMMAND ${CMAKE_ARGV0} -E echo_append "01 01 00 fe ff 0a"
+                COMMAND ${CMAKE_ARGV5}
+                COMMAND ${CMAKE_ARGV3})
+
+puff_cov_test("02 7e ff ff" "246")
+puff_cov_test("02" "2")
+puff_cov_test("04 80 49 92 24 49 92 24 0f b4 ff ff c3 04" "2")
+puff_cov_test("04 80 49 92 24 49 92 24 71 ff ff 93 11 00" "249")
+puff_cov_test("04 c0 81 08 00 00 00 00 20 7f eb 0b 00 00" "246")
+
+execute_process(COMMAND ${CMAKE_ARGV0} -E echo_append "0b 00 00"
+                COMMAND ${CMAKE_ARGV5}
+                COMMAND ${CMAKE_ARGV3})
+
+puff_cov_test("1a 07" "246")
+puff_cov_test("0c c0 81 00 00 00 00 00 90 ff 6b 04" "245")
+
+execute_process(COMMAND ${CMAKE_ARGV3} -f ${CMAKE_ARGV4}/zeros.raw)
+
+puff_cov_test("fc 00 00" "253")
+puff_cov_test("04 00 fe ff" "252")
+puff_cov_test("04 00 24 49" "251")
+puff_cov_test("04 80 49 92 24 49 92 24 0f b4 ff ff c3 84" "248")
+puff_cov_test("04 00 24 e9 ff ff" "250")
+puff_cov_test("04 00 24 e9 ff 6d" "247")
+
+execute_process(COMMAND ${CMAKE_ARGV6} ${CMAKE_ARGV7} -n puff.c.gcno)
diff --git a/archived/ptlibzippy/contrib/puff/test/tester.cmake b/archived/ptlibzippy/contrib/puff/test/tester.cmake
new file mode 100644
index 0000000000..3216d7c93c
--- /dev/null
+++ b/archived/ptlibzippy/contrib/puff/test/tester.cmake
@@ -0,0 +1,16 @@
+cmake_minimum_required(VERSION 3.12...3.31)
+
+#CMAKE_ARGV0 = ${CMAKE_COMMAND}
+#CMAKE_ARGV1 = -P
+#CMAKE_ARGV2 = ${CMAKE_CURRENT_SOURCE_DIR}/tester.cmake
+#CMAKE_ARGV3 = "$<TARGET_FILE:puff-test>"
+#CMAKE_ARGV4 = "${CMAKE_CURRENT_SOURCE_DIR}"
+
+execute_process(COMMAND ${CMAKE_ARGV3}
+                INPUT_FILE "${CMAKE_ARGV4}/zeros.raw"
+                RESULT_VARIABLE RESULT
+            COMMAND_ECHO STDERR)
+
+if(RESULT)
+    message(FATAL_ERROR "Command exitited with: ${RESULT}")
+endif(RESULT)